GDPR - регистрация доступа к серверу в точке аутентификации

В Великобритании проходит масштабная реформа политики защиты данных, известная как GDPR. Для одного клиента мы должны усилить аудит при доступе к определенным серверам нашей службой поддержки и разработки. Я хочу знать не только, кто вошел на удаленный рабочий стол сервера, но и почему. Я мог бы просто создать таблицу Excel или запись службы поддержки и попросить людей заполнять каждый раз, когда они входили в систему, но на самом деле она недостаточно надежна.

Я видел в других средах, что при входе на сервер (в форме входа в систему) отображается вторичная форма, спрашивающая, почему человек входит в систему. Вход в систему не разрешен, пока не будет заполнена дополнительная форма.

Я искал продукт, подобный этому, но не могу найти его. Кто-нибудь может порекомендовать какие-либо решения?

Источник

1 ответ

Решение

Ошибка сервера на самом деле не для рекомендаций продукта. Был похожий вопрос о SF в 2013 году, и в результате ОП создал сценарий входа в систему, спрашивая причину, пока он не будет дан, то есть не пуст:

<!-- language: lang-vb -->

' Display an input dialog asking the reason for a login and writes it to the event viewer with information of the user.

Const EVENT_TYPE = "Information" 'Available Values: Success, Error, Warning, Information
Const EVENT_SOURCE = "LoginAudit" 'Setting the event source requires that the script runs with administrative privileges

firstname = GetUserFirstname()
username = GetUsername()

loginReason = ""
Do While (loginReason = "")
    loginReason = InputBox("Hi " + firstname + ", please describe the reason of your login:", "Login Audit")
Loop

eventDescription = "User '" & username & "' logged in, providing the following reason: " & Chr(13) & Chr(13) & loginReason

Set WshShell = WScript.CreateObject("WScript.Shell")
strCommand = "eventcreate /T " & EVENT_TYPE & " /ID 100 /L Application /SO LoginAudit /D " & _
    Chr(34) & eventDescription & Chr(34)
WshShell.Run strcommand

Function GetUserFirstname()
  Set objSysInfo = CreateObject("ADSystemInfo")
  Set objCurrentUser = GetObject("LDAP://" & objSysInfo.UserName)
  GetUserFirstname = objCurrentUser.givenName
End Function

Function GetUsername()
  Set objNetwork = CreateObject("Wscript.Network")
  GetUsername = objNetwork.UserName
End Function

Вы можете изменить это, чтобы соответствовать вашим потребностям. Я думаю, что этот открытый подход к полевым формам привлекает предоставление однобуквенных ответов вместо реальных причин. Выпадающее меню может быть лучше, если все действия могут попадать в известные стандартные процедуры. Поскольку это часть работы, связанной с GDPR, вы, вероятно, уже подумали об этих процедурах обработки информации, позволяющей установить личность.

Источник
Другие вопросы по тегам