При входе в систему отображается диалоговое окно с запросом причины входа - Windows Server

Я ищу способ отображения диалогового окна ввода при входе в систему на производственном сервере, с просьбой указать причину входа в систему. Я подумал, может быть, в Windows есть способ сделать это, похожий на диалог выключения, который отображается при перезапуске сервера.

Я посмотрел в групповой политике, но не смог найти ничего полезного. Я знаю, что это можно сделать с помощью сценария, но я искал, есть ли какой-нибудь интегрированный способ в Windows, прежде чем я начну его писать.

Спасибо

Источник

2 ответа

Решение

В итоге я написал следующий VBScript и настроил его на вход в систему в GPO

' Display an input dialog asking the reason for a login and writes it to the event viewer with information of the user.

Const EVENT_TYPE = "Information" 'Available Values: Success, Error, Warning, Information
Const EVENT_SOURCE = "LoginAudit" 'Setting the event source requires that the script runs with administrative privileges

firstname = GetUserFirstname()
username = GetUsername()

loginReason = ""
Do While (loginReason = "")
    loginReason = InputBox("Hi " + firstname + ", please describe the reason of your login:", "Login Audit")
Loop

eventDescription = "User '" & username & "' logged in, providing the following reason: " & Chr(13) & Chr(13) & loginReason

Set WshShell = WScript.CreateObject("WScript.Shell")
strCommand = "eventcreate /T " & EVENT_TYPE & " /ID 100 /L Application /SO LoginAudit /D " & _
    Chr(34) & eventDescription & Chr(34)
WshShell.Run strcommand

Function GetUserFirstname()
    Set objSysInfo = CreateObject("ADSystemInfo")
    Set objCurrentUser = GetObject("LDAP://" & objSysInfo.UserName)
    GetUserFirstname = objCurrentUser.givenName
End Function

Function GetUsername()
    Set objNetwork = CreateObject("Wscript.Network")
    GetUsername = objNetwork.UserName
End Function
Источник

Я искал, есть ли какой-нибудь интегрированный способ в Windows, прежде чем я начну его писать.

Нет, нет Боюсь, тебе придется написать это самому. Возможно, существует стороннее приложение, которое делает то, что вы хотите, но я боюсь, что рекомендации по продукту / услуге не по теме здесь, из-за ошибки сервера.

Источник
Другие вопросы по тегам