Установка Lync 2013 Standard без вывода сообщений

Чтобы обойти проблемы с развертыванием с использованием файла MSP, вы можете использовать сценарий запуска для непосредственного вызова exe-файла и использовать конфигурацию xml для дополнительных параметров / ведения журнала.

Для начала создайте общую папку и поместите в нее файлы Lync 2013. Убедитесь, что вы предоставляете "доменным компьютерам" права на чтение и запись в эту папку (запись, если вы хотите вести журнал) и даете ей разрешения NTFS и Share.

Если вы хотите войти (и вы делаете), создайте папку для журналов в папке Install. Я назвал мой InstallLogFiles (Да, очень креативно).

В папке установки есть lync.www папка с config.xml файл. Отредактируйте файл и включите следующее:

<Display Level="none" CompletionNotice="no" SuppressModal="yes" AcceptEula="yes" />

<Logging Type="standard" Path="\\SERVER\SHARE\InstallLogFiles" Template="%computername%-Install_Log.txt" />

<!-- <USERNAME Value="Customer" /> -->

<!-- <COMPANYNAME Value="MyCompany" /> -->

<!-- <INSTALLLOCATION Value="%programfiles%\Microsoft Office" /> -->

<!-- <LIS CACHEACTION="CacheOnly" /> -->

 <LIS SOURCELIST="\\SERVER\SHARE" /> 

 <DistributionPoint Location="\\SERVER\SHARE" /> 

<!-- <OptionState Id="OptionID" State="absent" Children="force" /> -->

<Setting Id="SETUP_REBOOT" Value="never" />

<!-- <Command Path="%windir%\system32\msiexec.exe" Args="/i \\server\share\my.msi" QuietArg="/q" ChainPosition="after" Execute="install" /> -->

При необходимости вы можете изменить другие значения, но строки с \SERVER\SHARE\ должны указывать на папку установки.

Далее вам понадобится скрипт запуска для запуска на рабочих станциях для вызова установки. Следующий код и отредактируйте по мере необходимости и сохраните как файл.bat. Затем файл должен быть добавлен в групповую политику в качестве сценария запуска. Чтобы упростить развертывание, вы можете настроить политику так, чтобы она была доступна для чтения только группе AD. Затем вы можете добавить компьютеры, которые должны получить установку, в группу AD.

Код:

setlocal

REM *********************************************************************
REM Environment customization begins here. Modify variables below.
REM *********************************************************************

REM Get ProductName from the Office product's core Setup.xml file, and then add "office15." as a prefix.
set ProductName=Office15.LYNC

REM Set DeployServer to a network-accessible location containing the Office source files.
set DeployServer=\\SERVER\SHARE

REM Set ConfigFile to the configuration file to be used for deployment (required) 
set ConfigFile=\\SERVER\SHARE\lync.WW\config.xml

REM Set LogLocation to a central directory to collect log files.
set LogLocation=\\SERVER\SHARE\InstallLogFiles

REM *********************************************************************
REM Deployment code begins here. Do not modify anything below this line.
REM *********************************************************************

REM Skip install if OS is not Win 7 or above    

IF NOT "%ProgramFiles(x86)%"=="" (goto Office2013) else (goto XP)

:Office2013
REM Check to see if Office 2013 is installed, if so Exit
reg query HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Office15.PROPLUS
echo %date% %time% Checking if Office 2013 is installed code is %errorlevel%.>> %LogLocation%\%computername%.txt
if %errorlevel%==1 (goto ARP64) else (goto End)

REM Operating system is X64. Check if Lync is already installed in emulated Wow6432 uninstall key 
:ARP64 
reg query HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432NODE\Microsoft\Windows\CurrentVersion\Uninstall\%ProductName% 
echo %date% %time% Checking if Lync is installed code is %errorlevel%.>> %LogLocation%\%computername%.txt
if %errorlevel%==1 (goto Office) else (goto End)

REM Check to see if Office 2013 is installed, if so Exit
reg query HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Office15.PROPLUS
echo %date% %time% Checking if Office 2013 is installed code is %errorlevel%.>> %LogLocation%\%computername%.txt
if %errorlevel%==1 (goto Office) else (goto End)

REM If 1 returned, the product was not found. Run setup here.

:Office
echo %date% %time% Deployment triggered on %computername%.>> %LogLocation%\%computername%.txt
start /wait %DeployServer%\setup.exe /config %ConfigFile%
echo %date% %time% Setup ended with error code %errorlevel%. >> %LogLocation%\%computername%.txt
exit

:XP
echo %date% %time% Machine is Windows XP - Exiting >> %LogLocation%\%computername%.txt
exit 
REM If 0 or other was returned, the product was found or another error occurred. Do nothing.
:End
exit

Endlocal

Приведенный выше код проверит, является ли компьютер XP, если это выход / журнал.
Проверяет, установлен ли Office 2013, и завершите ли это /log.
Проверяет, установлен ли Lync 2013 Standalone, если это так, завершите работу.

Если это не так, он запускает установку и регистрирует свои шаги. Фактический журнал установки программного обеспечения также будет существовать, и оба будут настроены на использование %computername% переменная, чтобы помочь отследить проблемы.

Таким образом, я без проблем развернул Lync на сотнях машин.